HOW TO ADD RANGE USING EXPRESSIONS IN QUERY (strFmt('((%1.%2 ==) IN MICROSOFT DYNAMICS AX X++ CODE

HOW TO ADD RANGE USING EXPRESSIONS IN QUERY  strFmt('((%1.%2 ==

IN MICROSOFT DYNAMICS AX X++ CODE

static void AddRangeToQuery(Args _args)
{
    Query q = new Query();  // Create a new query.
    QueryRun qr;
    CustTable ct;
    QueryBuildDataSource qbr1;
    str strTemp;
    ;

    // Add a single datasource.
    qbr1 = q.addDataSource(tablenum(CustTable));
    // Name the datasource 'Customer'.
    qbr1.name("Customer");

    // Create a range value that designates an "OR" query like:
    // customer.AccountNum == "4000" || Customer.CreditMax > 2500.

    // Add the range to the query data source.
    qbr1.addRange(fieldNum(CustTable, AccountNum)).value(
    strFmt('((%1.%2 == "4000") || (%1.%3 > 2500))',
        qbr1.name(),
        fieldStr(CustTable, AccountNum),
        fieldStr(CustTable, CreditMax)));

    // Print the data source.
    print qbr1.toString();
    info(qbr1.toString());

    // Run the query and print the results.
    qr = new QueryRun(q);

    while (qr.next())
    {
        if (qr.changedNo(1))
        {
            ct = qr.getNo(1);
            strTemp = strFmt("%1 , %2", ct.AccountNum, ct.CreditMax);
            print strTemp;
            info(strTemp);
        }
    }
    pause;
}

CREATE ADD MODIFY AND DELETE AX x++ QUERY IN MICROSOFT DYNAMICS AX

CREATE ADD MODIFY AND DELETE AX x++ QUERY IN DYNAMICS AX

Static void CreateQueryJob(Args _args)
{
    TreeNode                treeNodeObj;
    Query                   queryObj; // Extends TreeNode class.
    QueryBuildDataSource    qbds;
    QueryBuildRange         qbr;
    QueryRun                qr;
    CustTable               xrecCustTable;
    str                     queryName = "MyQuery1";
    
    // Macro.
    #AOT

    // Delete the query from the AOT, if the query exists.
    treeNodeObj = TreeNode::findNode(#QueriesPath);
    treeNodeObj = treeNodeObj.AOTfindChild(queryName);
    if (treeNodeObj) { treeNodeObj.AOTdelete(); }

    // Add the query to the AOT.
    treeNodeObj = TreeNode::findNode(#QueriesPath);
    treeNodeObj.AOTadd(queryName);
    queryObj = treeNodeObj.AOTfindChild(queryName);
    
    // Further define the query.
    qbds  = queryObj.addDataSource(tablenum(CustTable));
    qbr   = qbds.addRange(fieldnum(CustTable, DlvMode));
    qbr.value(">10");

    // Compile the query.
    queryObj.AOTcompile(1);
    queryObj.AOTsave();

    // Run the query.
    qr = new QueryRun("MyQuery1");
    while ( qr.next() )
    {
        xrecCustTable = qr.GetNo(1); // 1 means first data source.
        Global::info(strFmt("%1 , %2",
            xrecCustTable.AccountNum, xrecCustTable.DlvMode));
    }        

    // Delete the query from the AOT.
    treeNodeObj = TreeNode::findNode(#QueriesPath);
    treeNodeObj = treeNodeObj.AOTfindChild(queryName);
    treeNodeObj.AOTdelete();
}

DYNAMICS AX CREATE CUSTOM NUMBER SEQUENCE X++ CODE SAMPLE

|| DYNAMICS AX NUMBER SEQUENCE ||

Suppose we want create number sequence for Test field on form in General  ledger module

Consideration: EDT-Test, Table-NumSeqTable and Form- NumSeqTable

Step1. Create new EDT with name Test

Step 2. Modify load module() method on  NumberSeqModuleLedger class

{

     datatype.parmDatatypeId(extendedTypeNum(Test));

     datatype.parmReferenceHelp(literalStr("Test"));

     datatype.parmWizardIsManual(NoYes::No);

     datatype.parmWizardIsChangeDownAllowed(NoYes::No);

     datatype.parmWizardIsChangeUpAllowed(NoYes::No);

     datatype.parmWizardHighest(999);

     datatype.parmSortField(30);

     datatype.addParameterType(NumberSeqParameterType::DataArea, true, false);

     this.create(datatype);

}

Step 3.Create a method on LedgerParameters Table

     client server static NumberSequenceReference numRefTest()

{

     return NumberSeqReference::findReference(extendedTypeNum(Test));

}

Step 4.Write and run following job

static void NumberSeqLoadAll(Args _args)

{

         NumberSeqApplicationModule::loadAll();

}

Step 5.Then run the wizard

Organization Administration -> CommonForms -> Numbersequences->Numbersequences-> Generate -> run the wizard.

Step 6.Now we have to check the number sequence  is correctly working  for that write a job:

static void NumSeq(Args _args)

{

    NumberSeq  numberSeq;

    Test num;

    ;

    numberSeq = NumberSeq::newGetNum(ProjParameters:: numRefTest ());

    num = numberSeq.num();

    info(num);

}

Step 7.Now we want that Number Sequence in form level(Test Table):

 Write below code in class declaration  

public class FormRun extends ObjectRun

{

    NumberSeqFormHandler numberSeqFormHandler;

}

 Step 8.Write the NumberSeqFormHandler() in form methods node.

NumberSeqFormHandler numberSeqFormHandler()

{

    if (!numberSeqFormHandler)

    {

       numberSeqFormHandler = NumberSeqFormHandler::newForm(LedgerParameters:: numRefTest ().NumberSequenceId,

                                                             element,

                                                             NumSeqTable_DS,

                                                             fieldNum(NumSeqTable, Test)

                                                            );

    }

    return numberSeqFormHandler;

}

Step 9.Write the  Create(),Delete(),Write() , Validate Write(),Link Active() on the Data source methods node.

 Create() Method

void create(boolean append = false,

            boolean extern = false) 

{

    element.numberSeqFormHandler().formMethodDataSourceCreatePre();

    super(append);

    if (!extern)

    {

        element.numberSeqFormHandler().formMethodDataSourceCreate(true);

    }

}

Delete() Method

public void delete()

{

    element.numberSeqFormHandler().formMethodDataSourceDelete();

    super();

}

Write()Method

public void write()

{

    super();

    element.numberSeqFormHandler().formMethodDataSourceWrite();

}

Validate Write() Method

public boolean validateWrite()

{

    boolean         ret;

    ret = super();

    ret = element.numberSeqFormHandler().formMethodDataSourceValidateWrite(ret) && ret;

    if (ret)

    {

        NumSeqTable.validateWrite();

    }

    return ret;

}

Link Active() Method

public void linkActive()

{

    ;

    element.numberSeqFormHandler().formMethodDataSourceLinkActive();

    super();

}

Step 10.Finally add Close() method on form 

void close()

{

    if (numberSeqFormHandler)

    {

        numberSeqFormHandler.formMethodClose();

    }

    super();

}